The Dget is the one and only Database function in Google Sheets that can use for vertical lookup. In Google Sheets, all Database functions are for Aggregation except the Dget. You can use the function Dget in Google Sheets in vertical lookup and return values from multiple columns, not rows.

If you want to use Dget to get data, you should make sure that your dataset complies with the following basic database requirements.

1. The data should be in tabular form and the top row of your data should contain field labels.

2. The table should not contain any duplicates. If there are duplicates, you should remove that by using the Unique or SORT function that you can use within the DGET. Because if there are multiple matches, Dget will return an error. This part also you can learn in this Google Sheets tutorial.

3. There shouldn’t be any merged cells in between your data range.

In other words, you can use the function Dget in Google Sheets in a structured dataset.

How to Use the Dget Function in Google Sheets

Syntax:

DGET(database, field, criteria)

This is the common syntax for all the database functions in Google Sheets like Dsum, Dproduct, Dcount, etc. Only the function name changes.

Details about the Function Arguments:

Note: No need to pay much attention to the arguments. You can learn the usage of the function Dget in Google Sheets from my examples itself.

Database:

The database is the array or range containing the data to consider. It should comply with the three points mentioned below the second paragraph of this tutorial.

Field:

The field is the field label or column number of the column which contains the values to be extracted and operated on.

If you know the use of Vlookup, you can compare the field in Dget with the Index Number in Vlookup.

Criteria:

The field is an array or range containing zero, one or more criteria by which to filter the database values before operating. In Vlookup terms, the criteria in Dget function are the search keys in Vlookup.

Examples of Google Sheets Dget Function

The below is a basic example of the use of the Dget function in Google Sheets.

See the Dget formula in cell F3. In this formula, the range A2:C6 is the database, F2 is the field and E2:E3 is the criteria.

What does this Dget formula do?

Since the field name (F2) in this formula is “price”, it returns a value from column C, which contains the label “price”, based on the criterion. The criterion is the “brand” name “C” in column A.

The above is the normal type use of the functions starting with the letter D in Google Sheets.

In such functions, the field and criteria are used as cell references and that’s the beauty of these functions.

But you can use the filed and criteria within the database formulas too. Here is an example.

=dget(A2:C6,"price",{"brand";"C"})

This Google Sheets Dget formula also returns the value 40 from the third column, which is the “price” field. Just like Vlookup, here also, you can replace the field label with the column number.

=dget(A2:C6,3,{"brand";"C"})

Vlookup Instead of Dget in Sheets

Let me give you one Vlookup example formula that replaces the above Dget formula.

=vlookup("C",A2:C6,3,false)

This formula can produce the same result that our above Dget formula provides.

To make you understand the difference I am trying to compare the arguments of Vlookup and Dget.

The range in both formulas is the same, i.e., A2:C6.

The search key/lookup key is “C” in Vlookup. In Google Sheets Dget formula, it’s called the criteria. There you should include the field label of the column containing the criteria.

In Vlookup the number 3 (3rd column) is the index column. From this column, the formula extracts the matching value. In Dget also the usage is the same.

How to Extract Multiple Column Values in Dget in Google Sheets

In Vlookup you can use multiple column index numbers. It’s possible in Dget too.

Dget Formula with Multiple Fields.

=ArrayFormula(dget(A2:C6,{2,3},{"brand";"C"}))

Vlookup Formula with Multiple Index Numbers.

=ArrayFormula(vlookup("C",A2:C6,{2,3},false))

Both of these formulas return the same result. See the below screenshot to understand the Dget formula clearly.

This example proves that Google Sheets Dget function can return multiple column outputs.

Similar: Multiple Values Using Vlookup in Google Sheets is Possible [How to]

How to Use Multiple Criteria in Dget in Google Sheets

Just like all other Database functions in Google Sheets, you can easily use multiple criteria in Dget if the criteria are used as cell references.

If you use the multiple criteria in Dget within the formula, then there is a tweak using Transpose. Thanks, Jan for sharing that tip via Comment.

=ArrayFormula(dget(A2:C6,3,transpose({"brand","C";"size","M"})))

Similar: How to Use VLOOKUP with Multiple Criteria in Google Sheets [Solved]

How to Handle Duplicates in Dget in Sheets

The multiple occurrences of items in the criteria field can cause an error in the Dget function output. In such cases, you can use the Unique or SORTN function to remove duplicates.

The generic formula would be like this. I am not going into any detail as it’s the rare case. In such cases better use Vlookup.

=DGET(unique(database), field, criteria)

Pros and Cons

Pros:

1. The Google Sheets Dget function is a database function. So if you have a structured data you can use it for vertical lookup. It can improve your Spreadsheet performance compared to Vlookup. It’s my point of view. I have not seen any official documentation regarding this.
2. In Dget function the Criteria (lookup column) position is not important. It can be from any column. But in Vlookup it should be the first column. But anyways, you can tweak that in Vlookup.

Cons:

1. The Dget formula returns #VALUE! error if the criterion doesn’t match. So you should wrap Google Sheets Dget formula with an Iferror.
2. You are not allowed to use multiple criteria in Dget function which is possible in Vlookup. Corrected this. Please see the details under the subtitle above “How to Use Multiple Criteria in Dget in Google Sheets”.
3. Duplicates in the criteria/lookup column are not allowed. This causes #NUM! error in DGET.