If you’ve ever dealt with strings that mix words and currency values in Google Sheets, you might have found it tricky to pull out just the numbers that come after a dollar sign—or any other currency symbol.

In this post, I’ll show you how to extract numbers prefixed by currency signs from a text string in Google Sheets. Whether it’s a single value or multiple amounts scattered in a sentence, there’s a formula for it.

Why Extract Numbers Prefixed by Currency Signs?

Let’s say you have this text in a cell:

You have to pay $20.50 to Mr. A and $50 to B before 10 am.

You want to extract only the $20.50 and $50, and ignore the 10, since that’s just a time reference.

Extract the First Currency Number

If you’re just looking to grab the first number that comes after a dollar sign, this formula works:

=REGEXEXTRACT(A1, "\$(\d+(?:\.\d+)?)")

What it does:

• Looks for a dollar sign followed by one or more digits.
• Grabs decimal values too (like 20.50).

This returns 20.50 from the example above.

Extract the Second One

To get the second dollar amount, you can use:

=REGEXEXTRACT(A1, "\$(?:\d+(?:\.\d+)?).*?\$(\d+(?:\.\d+)?)")

This skips the first one and captures the next $-prefixed number—in this case, 50.

Extract All Currency-Prefixed Numbers

Now, what if there are more than two? You’ll need a formula that can pull out all the values dynamically.

Here’s one that works nicely:

=ArrayFormula(TOROW(REGEXEXTRACT(TO_TEXT(SPLIT(SUBSTITUTE(A1, "$", "~$"), "~")), "\$(\d+(?:\.\d+)?)"), 3))

How it works:

1. SUBSTITUTE(A1, "$", "~$") inserts a ~ before each dollar sign, creating a reliable split point.

You have to pay ~$20.50 to Mr. A and ~$50 to B before 10 am.

2. SPLIT(..., "~") breaks the text into chunks so that each dollar-prefixed number stands alone.

3. TO_TEXT(...) ensures all parts are treated as text (important for REGEXEXTRACT to work reliably).

4. REGEXEXTRACT(..., "\$(\d+(?:\.\d+)?)") extracts the number following each dollar sign.

5. TOROW(...) removes any #N/A or empty results and returns the final values in a single row.

Note: The purpose of TOROW here isn’t to flatten the result (the array is already one-dimensional); it’s to clean the output by removing any non-matches or blanks.

You’ll get something like:

If you want the results in a column instead, just replace TOROW with TOCOL.

Sum the Extracted Currency Values

You can even total them with this formula:

=ArrayFormula(SUM(VALUE(TOROW(REGEXEXTRACT(TO_TEXT(SPLIT(SUBSTITUTE(A1, "$", "~$"), "~")), "\$(\d+(?:\.\d+)?)"), 3))))

This does the same extraction but wraps the results in VALUE (to convert from text to number), and then adds them up.

From our example, it returns:

70.5

Adapt for Other Currency Symbols

This approach works with other currency signs too—just replace $ in the formulas with €, £, ₹, or whatever you’re using.

For example, to extract values with the euro sign (€), use:

=ArrayFormula(TOROW(REGEXEXTRACT(TO_TEXT(SPLIT(SUBSTITUTE(A1, "€", "~€"), "~")), "\€(\d+(?:\.\d+)?)"), 3))

Conclusion

Extracting numbers prefixed by currency signs in Google Sheets doesn’t have to be complicated. With a little help from REGEXEXTRACT, SPLIT, and ARRAYFORMULA, you can quickly pull out just the values you care about—and ignore the rest.

This is especially helpful if you’re dealing with receipts, invoices, or any mixed-text fields where numbers and currency symbols live side by side.

Related Reading

• Extract All Numbers from Text and SUM It in Google Sheets
• How to Set Your Country’s Currency Format in Google Sheets
• Currency Conversion in Google Sheets Using GOOGLEFINANCE
• Convert Currency-Formatted Text to Numbers in Google Sheets
• Format Numbers as Currency Using Formulas in Google Sheets
• Currency Formatting in Google Sheets Drop-Downs