In this quick tutorial, you’ll find several formula options to extract the decimal part of a number in Google Sheets. The number can be either positive or negative.

In one of my earlier posts, I included a formula as part of a combo setup to extract the decimal part of a number in Google Sheets—but I didn’t go into the details there.

For example, in the tutorial How to Filter and Work with Decimal Numbers in Google Sheets, you can see one such formula in action.

To get the decimal part in Google Sheets, we can use at least three formulas (maybe more). I’ve used one of them in the linked tutorial above.

In this post, I’ll walk you through the most commonly used formulas to get the decimal part of positive or negative numbers in Google Sheets.

Formula to Extract Decimal Part in Google Sheets

Let’s begin with the most common approach—using the INT function.

INT-Based Formula

In all the examples below, assume the value in cell B2 is 11.256, unless otherwise specified.

We can use the following INT formula to extract the integer part of the number:

=INT(B2)

This returns 11. That means to extract the decimal part, we can subtract the integer from the original number using this formula:

=B2 - INT(B2)

This INT-based formula returns the decimal part: 0.256.

Now change the number in B2 to a negative value like -11.256. The result will be 0.744!

Why? Because the INT function returns -12 as the integer part of -11.256—it rounds down to the next lowest integer, not toward zero.

So, to get the correct decimal part, we must convert the number to its absolute value first:

Formula 1 – Using INT and ABS

=ABS(B2) - INT(ABS(B2))

Result: 0.256

This works correctly for both positive and negative numbers.

MOD-Based Formula

Another way to extract the decimal part in Google Sheets is with the MOD function:

=MOD(B2, 1)

This works fine for positive numbers like 11.256, returning 0.256.

But with a negative number like -11.256, it returns 0.744, just like the INT formula.

To fix this, we can again wrap the input with the ABS function:

Formula 2 – Using MOD and ABS

=MOD(ABS(B2), 1)

Result: 0.256

This version returns the correct decimal part regardless of the number’s sign.

TRUNC to Extract Negative Decimal Part in Google Sheets

In both formulas above (Formula 1 and Formula 2), the extracted decimal part is always positive—even if the original number is negative.

But what if you want to preserve the sign?

For example, for -11.256, you may want the decimal part to be -0.256 instead of 0.256.

In that case, use this formula based on TRUNC:

Formula 3 – Signed Decimal Part

=B2 - TRUNC(B2)

This formula preserves the sign of the decimal part. For example:

• 11.256 returns 0.256
• -11.256 returns -0.256

If you’d rather get the positive decimal part from this (like in the INT and MOD examples), you can wrap it with ABS:

Formula 4 – Unsigned Decimal Part Using TRUNC

=ABS(B2 - TRUNC(B2))

Result: 0.256

Summary of Formulas to Extract Decimal Part in Google Sheets

To summarize, here are four formulas to extract the decimal part of a number in Google Sheets:

That’s it! I hope this helped you understand how to extract the decimal or fractional part from a number in Google Sheets—whether it’s positive or negative.

If you have any related questions, feel free to drop them in the comments.